Aspect of the Turtle Cancelaura

The game's built-in re-press cancel has a grace period. This skips it, letting you activate and then immediately cancel Turtle. Do NOT use this if you spam Turtle, it needs deliberate single key presses to toggle on and off.

#showtooltip Aspect of the Turtle
/stopcasting
/stopcasting
/use Aspect of the Turtle
/cancelaura Aspect of the Turtle

Auto Kick / Stun

Uses your interrupt on a random casting target with no targeting, mouseover, or focus needed. Great for lower or uncoordinated keys: see a cast, hit the macro. The third version does the same for Intimidation.

#showtooltip Counter Shot
/cast [@focus,exists,nodead,harm] Counter Shot
/stopmacro [@focus,exists,nodead,harm]
/focus target
/cleartarget
/targetenemy
/cast Counter Shot
/target focus
/clearfocus
/startattack

#showtooltip Muzzle
/cast [@focus,exists,nodead,harm] Muzzle
/stopmacro [@focus,exists,nodead,harm]
/focus target
/cleartarget
/targetenemy
/cast Muzzle
/target focus
/clearfocus
/startattack

#showtooltip
/cast [@focus,exists,nodead,harm] Intimidation
/stopmacro [@focus,exists,nodead,harm]
/focus target
/cleartarget
/targetenemy
/cast Intimidation
/target focus
/clearfocus
/startattack

It prefers kicking your focus if you have one. To prefer your mouseover instead, swap "focus" for "mouseover".

Cursor Cast (ground-targeted abilities)

Skips the green targeting circle for ground-targeted abilities. I use it for everything from Flare to Traps to Binding Shot to Volley. Just place your cursor where you want it.

#showtooltip
/use [@cursor]Freezing Trap

#showtooltip
/use [@cursor]Tar Trap

#showtooltip
/use [@cursor]Binding Shot

#showtooltip
/use [@cursor]Volley

#showtooltip
/use [@cursor]Flare

Disengage StopCasting

Stops casts like Steady Shot and forces a Disengage, but will not cancel channels like Rapid Fire or Boomstick that you can actually Disengage in the middle of.

#showtooltip Disengage
/stopcasting [nochanneling:rapid fire]
/stopcasting [nochanneling:boomstick]
/use Disengage

Focus Mouseover

Essential for serious Mythic+. Sets your mouseover as your focus and marks it with a green marker (unless it already has one), so the kick macros below can hit it.

/focus [@mouseover,exists,nodead][]
/tm [@mouseover,exists,nodead][] 4

Mouseover Master's Call

Casts Master's Call on your mouseover if it's a friendly, living target, otherwise on yourself.

#showtooltip
/use [@mouseover,help,nodead][@player]Master's Call(Cunning Ability)

Mouseover Multi-Shot

Mainly for MM, which may want to Multi-Shot something separate from its main target just to activate Trick Shots, but it works fine for BM too so I recommend it for both.

#showtooltip Multi-Shot
/stopmacro [channeling:Rapid Fire]
/use [@mouseover,exists,harm,nodead][]Multi-Shot
/petattack
/petassist

Mouseover Tranq Shot

Tranqs your mouseover enemy, or your target if there is no valid mouseover.

#showtooltip
/use [@mouseover,exists,harm,nodead][]Tranquilizing Shot

Pet Reset

Useful when jumping off ledges where you really want your pet to follow. Petpassive and petfollow make the pet snap to you more readily; the Dash line gets it back to you as fast as possible.

/petpassive
/petfollow
/use Dash

Pet Taunt

In Mythic+ it can be useful to taunt a powerful mob right before a tank buster to help save your tank. Use a Beetle, Boar, Carapid (BM only), Core Hound (BM only), Mechanical, Scalehide, Shale Beast (BM only), or Turtle, they have a 50% DR on a 1-min CD.

#showtooltip
/use [@mouseover,exists,harm][@focus,exists,harm]Growl
/use Scale Shield
/use Harden Carapace
/use Bristle
/use Bulwark
/use Obsidian Skin
/use Defense Matrix
/use Solid Shell
/use Shell Shield

Smart Misdirection (WeakAura / AddOn)

Automatically Misdirects the tank in your group, no targeting or focusing needed. Grab the TankMD addon, set up the macro below, and put it on your bars.

#showtooltip Misdirection
/click TankMDButton1

Auto Pet-Summon Kill Command

Summons or resurrects your pet if you don't have one out, otherwise it's a normal Kill Command. Set the Call Pet number to your default pet; when Lusting I swap it to my Lust pet's number so a mid-key death still summons the right pet. The res part isn't 100% reliable if the pet unit isn't present, so keep Revive Pet bound separately too.

#showtooltip Kill Command
/petassist
/petattack
/cast [@pet,dead] Revive Pet;
/cast [@pet,noexists,mod:shift] Revive Pet;
/cast [@pet,noexists] Call Pet 1;
/cast Kill Command

Barbed Shot Mouseover (multidotting)

Multidotting Barbed Shot on AoE is essential. Prefers your mouseover target, or your current target if there isn't one.

#showtooltip
/use [@mouseover,harm,nodead][]Barbed Shot

Bestial Wrath Cancelaura (Shroud/Camo)

Opening Bestial Wrath from Camo or Shroud in Pack Leader can glitch out Howl of the Pack Leader and stop your beasts spawning, a big DPS loss. This macro makes sure that can't happen.

#showtooltip
/cancelaura Shroud of Concealment
/cancelaura Camouflage
/use Bestial Wrath

Black Arrow Cancelaura + Mouseover

Same glitch can happen with Black Arrow and Deathblow procs. This also prefers your mouseover for Black Arrow, essential for the many cases where you can Black Arrow a secondary target but not your main one, or want to hit a prio target that's currently out of AoE position. The nochanneling line is an MM addition that stops the cast cancelling Rapid Fire.

#showtooltip Black Arrow
/cancelaura Shroud of Concealment
/cancelaura Camouflage
/stopmacro [channeling:Rapid Fire]
/use [@mouseover,exists,harm][]Black Arrow

Nochanneling ability macros

Every offensive ability should carry a nochanneling Rapid Fire clause so that no matter how hard you spam, you never clip or cancel your Rapid Fire channel. Here's how to do it across the kit.

#showtooltip
/petattack
/use [nochanneling:Rapid Fire]Aimed Shot

#showtooltip
/petattack
/use [nochanneling:Rapid Fire]Arcane Shot

#showtooltip Kill Shot
/stopmacro [channeling:Rapid Fire]
/use [@mouseover,exists,harm][]Kill Shot

#showtooltip Black Arrow
/stopmacro [channeling:Rapid Fire]
/use [@mouseover,exists,harm][]Black Arrow

#showtooltip Explosive Shot
/stopmacro [channeling:Rapid Fire]
/use [@mouseover,exists,harm][]Explosive Shot

#showtooltip
/stopmacro [channeling:Rapid Fire]
/use [@mouseover,exists,harm][]Multi-Shot
/petattack
/petassist

#showtooltip
/use [nochanneling:Rapid Fire]Rapid Fire

#showtooltip Steady Shot
/use [nochanneling:Rapid Fire]Steady Shot

#showtooltip Volley
/stopmacro [channeling:Rapid Fire]
/use [@cursor]Volley

#showtooltip
/stopmacro [channeling:Rapid Fire]
/use Trueshot
/use Blood Fury
/use Berserking
/use Ancestral Call(Racial)

Harpoon Mouseover

For quick position changes to a specific target without changing your DPS target. Also just feels cool af.

#showtooltip
/use [@mouseover,exists,harm][]harpoon
/cancelaura Updraft

Nochanneling ability macros

Every offensive ability should carry a nochanneling Boomstick clause so that no matter how hard you spam, you never clip or cancel your Boomstick channel. Here's how to do it across the kit.

#showtooltip
/petattack
/use [nochanneling:Boomstick]Raptor Strike

#showtooltip
/petattack
/use [nochanneling:Boomstick]Kill Command

#showtooltip
/stopmacro [channeling:Boomstick]
/use [@mouseover,exists,harm][]Wildfire Bomb

#showtooltip
/use [nochanneling:Boomstick]Boomstick

#showtooltip
/stopmacro [channeling:Boomstick]
/use Takedown
/use Blood Fury
/use Berserking
/use Ancestral Call(Racial)

#showtooltip
/stopmacro [channeling:Boomstick]
/use Aspect of the Eagle
/use [nochanneling:Boomstick]Raptor Strike

Wildfire Bomb Mouseover

Wildfire Bomb is both a cone behind your target and a circle around it. In spread AoE you may have to rely on the cone alone, and mouseover Bombing is extremely potent for maximizing coverage.

#showtooltip Wildfire Bomb
/petattack
/use [@mouseover,harm,nodead,exists][]Wildfire Bomb